TinyAdventure/scenes/game.gd

class_name Game
extends Node3D

@onready var message_container:Control = %MessagesContainer
@onready var message_textedit:TextEdit = %MessageTextEdit

@onready var player = %Player
@onready var builder_missing_tool = %BuilderMissingTool

@onready var root_ui:RootUI = %RootUI

func save_game():
	var save_game:SaveGame = SaveGame.new()
	
	save_game.player_transform = player.global_transform
	
	for node:Node in get_tree().get_nodes_in_group("quest_state"):
		save_game.quest_states[node.name] = {}
		
		for property in node.get_property_list():
			if (property.usage & PROPERTY_USAGE_STORAGE != 0) and (property.usage & PROPERTY_USAGE_SCRIPT_VARIABLE) != 0:
				save_game.quest_states[node.name][property.name] = node.get(property.name)

	ResourceSaver.save(save_game, "user://savegame.tres")
	root_ui.activate_ui_panel(%GameUI)

func load_game():
	var save_game:SaveGame = load("user://savegame.tres") as SaveGame

	player.global_transform = save_game.player_transform
	
	for node:Node in get_tree().get_nodes_in_group("quest_state"):
		for property in node.get_property_list():
			if (property.usage & PROPERTY_USAGE_STORAGE != 0) and (property.usage & PROPERTY_USAGE_SCRIPT_VARIABLE) != 0:
				node.set(property.name, save_game.quest_states[node.name][property.name])
	
	root_ui.activate_ui_panel(%GameUI)