TinyAdventure/player.gd

class_name Player
extends CharacterBody3D

const SPEED = 5.0
const JUMP_VELOCITY = 2.5

@onready var geometry = %Geometry
@onready var actionable_detector = %ActionableDetector
@onready var quest_state = %QuestState
@onready var bridge = %Bridge

# Get the gravity from the project settings to be synced with RigidBody nodes.
var gravity = ProjectSettings.get_setting("physics/3d/default_gravity")
var inventory:Inventory = Inventory.new()

var last_nonzero_velocity:Vector3 = Vector3.BACK

signal trigger_message(message:String)

func _physics_process(delta):
	# Add the gravity.
	if not is_on_floor():
		velocity.y -= gravity * delta

	# Get the input direction and handle the movement/deceleration.
	# As good practice, you should replace UI actions with custom gameplay actions.
	var input_dir = Input.get_vector("walk_left", "walk_right", "walk_forward", "walk_back")
	var direction = (transform.basis * Vector3(input_dir.x, 0, input_dir.y)).normalized()
	if direction:
		velocity.x = direction.x * SPEED
		velocity.z = direction.z * SPEED
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
		velocity.z = move_toward(velocity.z, 0, SPEED)

	move_and_slide()
	
	var ground_velocity:Vector2 = Vector2(velocity.x, velocity.z)
	
	if ground_velocity.length_squared() > 0.1 * 0.1:
		last_nonzero_velocity = Vector3(ground_velocity.x, 0, ground_velocity.y).normalized()

	geometry.look_at(position - last_nonzero_velocity, Vector3.UP)


func on_item_picked_up(item:Item):
	emit_signal("trigger_message", "Picked up a " + item.name)
	inventory.add_item(item)


func _unhandled_input(_event: InputEvent) -> void:
	if Input.is_action_just_pressed("ui_accept"):
		var actionables = actionable_detector.get_overlapping_areas()
		if actionables.size() > 0:
			actionables[0].action(quest_state)