TinyAdventure/scenes/main.gd

class_name Main
extends Node3D

@onready var message_container:Control = %MessagesContainer
@onready var message_textedit:TextEdit = %MessageTextEdit

@onready var builder_missing_tool = %BuilderMissingTool

@onready var root_ui:RootUI = %RootUI

func save_game():
	var player:Player = find_child("Player", true, false)

	if player == null:
		push_error("Cannot load game: no player found!")
		return

	var save_game:SaveGame = SaveGame.new()
	
	save_game.player_transform = player.global_transform
	
	for node:Node in get_tree().get_nodes_in_group("quest_state"):
		save_game.quest_states[node.name] = {}

		for property in node.get_property_list():
			if (property.usage & PROPERTY_USAGE_STORAGE != 0) and (property.usage & PROPERTY_USAGE_SCRIPT_VARIABLE) != 0:
				save_game.quest_states[node.name][property.name] = node.get(property.name)

	for item in player.inventory.get_items():
		save_game.inventory.append(item)

	ResourceSaver.save(save_game, "user://savegame.tres")
	root_ui.activate_ui_panel(%GameUI)

func load_game():
	var player:Player = find_child("Player", true, false)
	
	if player == null:
		push_error("Cannot load game: no player found!")
		return
	
	var save_game:SaveGame = load("user://savegame.tres") as SaveGame

	player.global_transform = save_game.player_transform
	
	for node:Node in get_tree().get_nodes_in_group("quest_state"):
		for property in node.get_property_list():
			if (property.usage & PROPERTY_USAGE_STORAGE != 0) and (property.usage & PROPERTY_USAGE_SCRIPT_VARIABLE) != 0:
				node.set(property.name, save_game.quest_states[node.name][property.name])
	
	player.inventory.clear()
	for item in save_game.inventory:
		player.inventory.add_item(item)
	
	root_ui.activate_ui_panel(%GameUI)