DashBoomColorClash/entities/Player.gd

class_name Player extends CharacterBody3D

@export var color : Color = Color.DODGER_BLUE

@export var move_right_action := "move_right"
@export var move_left_action := "move_left"
@export var move_down_action := "move_down"
@export var move_up_action := "move_up"
@export var dash_action := "dash"
@export var bomb_action := "bomb"

@export var coloring_sprite_path : NodePath
@export var coloring_bomb_sprite_path : NodePath

@onready var geometry: MeshInstance3D = $Geometry
@onready var collision: CollisionShape3D = $CollisionShape3D
@onready var dash_stream_player: AudioStreamPlayer = $DashAudioStreamPlayer
@onready var explosion_stream_player: AudioStreamPlayer = $ExplosionAudioStreamPlayer
@onready var spawn_stream_player: AudioStreamPlayer = $SpawnAudioStreamPlayer

var bomb_emitter_scene = preload("res://entities/BombEmitter.tscn")

enum PlayerState {
	Alive = 0,
	Falling,
	Dead
}

var score : int = 0
var energy : float = 100.0
var state : PlayerState = PlayerState.Alive
var state_last : PlayerState = PlayerState.Dead

var radius = 0.15
var angle = 0
var is_dashing = false
var explosion_velocity: Vector3 = Vector3.ZERO
var explosion_influence: float = 0
var dash_time = 0
var bomb_time = 0
var coloring_sprite : Sprite2D
var coloring_bomb_sprite : Sprite2D

const SPEED = 5.0
const DASH_SPEED: float = 20
const DASH_DURATION: float = 0.2
const DASH_ENERGY: float = 40
const BOMB_DURATION: float = 0.1
const BOMB_ENERGY: float = 60
const ENERGY_REPLENISH_RATE: float = 0.5;
const EXPLOSION_INFLUENCE_REDUCTION_RATE: float = 10.0;

# Get the gravity from the project settings to be synced with RigidBody nodes.
var gravity = ProjectSettings.get_setting("physics/3d/default_gravity")

func _ready():
	coloring_sprite = get_node(coloring_sprite_path)
	coloring_bomb_sprite = get_node(coloring_bomb_sprite_path)
	coloring_sprite.modulate = color
	coloring_sprite.visible = true
	coloring_bomb_sprite.modulate = color
	coloring_bomb_sprite.visible = false

func _physics_process(delta):
	if energy < 100:
		energy = min (100, energy + delta + ENERGY_REPLENISH_RATE)
	
	if state_last != state:
		if state == PlayerState.Alive:
			on_player_spawn()
		elif state == PlayerState.Falling:
			on_player_falling()
		elif state == PlayerState.Dead:
			on_player_dead()
			
		state_last = state
	
	if global_position.y < -5:
		state = PlayerState.Dead
	elif not is_on_floor():
		if not is_dashing:
			velocity.y -= gravity * delta
			state = PlayerState.Falling
	elif state != PlayerState.Dead:
		state = PlayerState.Alive
	elif state == PlayerState.Dead:
		visible = false
		return
	elif state == PlayerState.Alive:
		visible = true

	coloring_sprite.visible = state == PlayerState.Alive

	if bomb_time > 0:
		bomb_time -= delta
		if bomb_time <= 0:
			coloring_bomb_sprite.visible = false
			bomb_time = 0
	else:
		if Input.is_action_just_pressed(bomb_action) \
			and state == PlayerState.Alive \
			and energy > BOMB_ENERGY:
			on_drop_bomb()
		
	# Get the input direction and handle the movement/deceleration.
	# As good practice, you should replace UI actions with custom gameplay actions.
	var input_dir = Input.get_vector(move_left_action, move_right_action, move_up_action, move_down_action)
	var direction = (transform.basis * Vector3(input_dir.x, 0, input_dir.y)).normalized()
	if direction:
		velocity.x = direction.x * SPEED
		velocity.z = direction.z * SPEED
		angle = direction.signed_angle_to(Vector3.FORWARD, Vector3.UP)
		geometry.global_basis = Basis.from_euler(Vector3(0, -angle, 0))
	else:
		velocity.x = move_toward(velocity.x, 0, SPEED)
		velocity.z = move_toward(velocity.z, 0, SPEED)
		geometry.global_basis = Basis.from_euler(Vector3(0, -angle, 0))
	
	if Input.is_action_just_pressed(dash_action) \
		and state == PlayerState.Alive \
		and energy > DASH_ENERGY:
		on_dash()
		
	if is_dashing:
		velocity.x = sin(angle) * DASH_SPEED
		velocity.z = -cos(angle) * DASH_SPEED
		
		geometry.global_basis = Basis.from_euler(Vector3(-0.3, -angle, 0))
		
		dash_time -= delta
		if dash_time <= 0:
			is_dashing = false
	
	if explosion_influence > 0:
		velocity += explosion_velocity
		explosion_influence = max (0, explosion_influence - EXPLOSION_INFLUENCE_REDUCTION_RATE * delta)
	
	move_and_slide()

	coloring_sprite.global_position = calc_coloring_position()
	coloring_bomb_sprite.global_position = coloring_sprite.global_position

func calc_coloring_position():
	var result = Vector2 (global_position.x * 10 + 512, global_position.z * 10 + 512)
	return result;

func on_player_spawn():
	print ("Player " + 	str(name) + ": spawning")
	spawn_stream_player.pitch_scale = 0.8 + randf () * 0.4
	spawn_stream_player.play()

func on_player_falling():
	print ("Player " + str(name) + ": falling")

func on_player_dead():
	print ("Player " + str(name) + ": death")

func on_dash():
	is_dashing = true;
	dash_time = DASH_DURATION
	energy = max (0, energy - DASH_ENERGY)
	dash_stream_player.pitch_scale = 0.9 + randf () * 0.2
	dash_stream_player.play()
	
func on_drop_bomb():
	coloring_bomb_sprite.visible = true;
	bomb_time = BOMB_DURATION
	energy = max (0, energy - BOMB_ENERGY)

	explosion_stream_player.pitch_scale = 0.6 + randf () * 0.2
	explosion_stream_player.play()

	var bomb_emitter : BombEmitter = bomb_emitter_scene.instantiate()
	get_parent_node_3d().add_child(bomb_emitter)
	bomb_emitter.global_position = global_position