50 lines
2.6 KiB
CMake
50 lines
2.6 KiB
CMake
|
|
add_custom_command(
|
|
DEPENDS $<$<BOOL:${ozz_build_fbx}>:BUILD_DATA>
|
|
"${CMAKE_CURRENT_LIST_DIR}/README.md"
|
|
"${ozz_media_directory}/bin/pab_skeleton.ozz"
|
|
"${ozz_media_directory}/bin/pab_crossarms.ozz"
|
|
OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/README.md"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/media/skeleton.ozz"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/media/animation.ozz"
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory media
|
|
COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_CURRENT_LIST_DIR}/README.md" .
|
|
COMMAND ${CMAKE_COMMAND} -E copy "${ozz_media_directory}/bin/pab_skeleton.ozz" "./media/skeleton.ozz"
|
|
COMMAND ${CMAKE_COMMAND} -E copy "${ozz_media_directory}/bin/pab_crossarms.ozz" "./media/animation.ozz"
|
|
VERBATIM)
|
|
|
|
add_executable(sample_playback
|
|
sample_playback.cc
|
|
"${CMAKE_CURRENT_BINARY_DIR}/README.md"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/media/skeleton.ozz"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/media/animation.ozz")
|
|
target_link_libraries(sample_playback
|
|
sample_framework)
|
|
|
|
set_target_properties(sample_playback
|
|
PROPERTIES FOLDER "samples")
|
|
|
|
if(EMSCRIPTEN)
|
|
# Resource files are embedded to the output file with emscripten
|
|
set_target_properties(sample_playback
|
|
PROPERTIES LINK_FLAGS "--embed-file media --embed-file README.md --memory-init-file 0")
|
|
|
|
install(FILES
|
|
${CMAKE_CURRENT_BINARY_DIR}/sample_playback.html
|
|
${CMAKE_CURRENT_BINARY_DIR}/sample_playback.js
|
|
${CMAKE_CURRENT_BINARY_DIR}/sample_playback.wasm
|
|
DESTINATION bin/samples/playback)
|
|
else()
|
|
install(TARGETS sample_playback DESTINATION bin/samples/playback)
|
|
install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/media DESTINATION bin/samples/playback)
|
|
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/README.md DESTINATION bin/samples/playback)
|
|
endif(EMSCRIPTEN)
|
|
|
|
add_test(NAME sample_playback COMMAND sample_playback "--max_idle_loops=${ozz_sample_testing_loops}" $<$<BOOL:${ozz_run_tests_headless}>:--norender>)
|
|
add_test(NAME sample_playback_path1 COMMAND sample_playback "--skeleton=media/skeleton.ozz" "--animation=media/animation.ozz" "--max_idle_loops=${ozz_sample_testing_loops}" $<$<BOOL:${ozz_run_tests_headless}>:--norender>)
|
|
add_test(NAME sample_playback_invalid_skeleton_path COMMAND sample_playback "--skeleton=media/bad_skeleton.ozz" $<$<BOOL:${ozz_run_tests_headless}>:--norender>)
|
|
set_tests_properties(sample_playback_invalid_skeleton_path PROPERTIES WILL_FAIL true)
|
|
add_test(NAME sample_playback_invalid_animation_path COMMAND sample_playback "--animation=media/bad_animation.ozz" $<$<BOOL:${ozz_run_tests_headless}>:--norender>)
|
|
set_tests_properties(sample_playback_invalid_animation_path PROPERTIES WILL_FAIL true)
|
|
|